Introduction

This article is going to discuss two ways of displaying the DataLinks dialog to facilitate user entry of connection strings.  The code you will see here is from a minimalist’s perspective, since I myself like to write as few lines and include as little code as possible to get the job done.  I will show two approaches available to VB.net developers to include the DataLinks dialog without the need include any additional references. (aaaha you guessed it late-binding)

Most applications today use some means of persisting data, and to this end the relational database is the method of choice.  DotNet developers know that in order to anything with a relational database you must first be able to connect to that database.

Code

Private Sub VB6StyleReflection()
        Dim dlink As Object = CreateObject("Datalinks")
        CallByName(dlink, "hWnd", CallType.Let, Me.Handle.ToInt32)
        If txtConnectionString.Text = String.Empty Then
            Dim conn As Object = CallByName(dlink, "PromptNew", CallType.Method)
            If Not Object.Equals(conn, Nothing) Then
                txtConnectionString.Text = CType(CallByName(conn, "ConnectionString", CallType.Get), String)
                System.Runtime.InteropServices.Marshal.ReleaseComObject(conn)
            End If
        Else
            Dim conn As Object = CreateObject("ADODB.Connection")
            CallByName(conn, "ConnectionString", CallType.Let, txtConnectionString.Text)
            If CType(CallByName(dlink, "PromptEdit", CallType.Method, conn), Boolean) Then
                txtConnectionString.Text = CType(CallByName(conn, "ConnectionString", CallType.Get), String)
            End If
            System.Runtime.InteropServices.Marshal.ReleaseComObject(conn)
        End If
        System.Runtime.InteropServices.Marshal.ReleaseComObject(dlink)
End Sub

Private Sub DotNetStyleReflection()
        Dim dlinkType As Type = Type.GetTypeFromProgID("Datalinks", True)
        Dim dlink As Object = Activator.CreateInstance(dlinkType)
        dlinkType.InvokeMember("hWnd", BindingFlags.SetProperty Or 
         BindingFlags.Public Or BindingFlags.Instance, 
         Nothing, 
         dlink, 
         New Object() {Me.Handle.ToInt32})
        If txtConnectionString.Text = String.Empty Then
            Dim conn As Object = dlinkType.InvokeMember("PromptNew", 
             BindingFlags.InvokeMethod Or BindingFlags.Public Or BindingFlags.Instance , 
              Nothing, 
              dlink, 
              Nothing)
            If Not Object.Equals(conn, Nothing) Then
                Dim connType As Type = conn.GetType()
                txtConnectionString.Text = DirectCast(connType.InvokeMember("ConnectionString", 
                 BindingFlags.GetProperty Or BindingFlags.Instance Or BindingFlags.Public, 
                 Nothing, 
                 conn, 
                 Nothing), String)
                System.Runtime.InteropServices.Marshal.ReleaseComObject(conn)
            End If
        Else
            Dim connType As Type = Type.GetTypeFromProgID("ADODB.Connection", True)
            Dim conn As Object = Activator.CreateInstance(connType)
            connType.InvokeMember("ConnectionString", 
             BindingFlags.SetProperty Or BindingFlags.Instance Or BindingFlags.Public, 
             Nothing, 
             conn, 
             New Object() {txtConnectionString.Text})
            If DirectCast(dlinkType.InvokeMember("PromptEdit", 
            BindingFlags.InvokeMethod Or BindingFlags.Public Or BindingFlags.Instance, 
             Nothing, 
             dlink, New Object() {conn}), 
             Boolean) Then
                 txtConnectionString.Text = DirectCast(connType.InvokeMember("ConnectionString", 
                  BindingFlags.GetProperty Or BindingFlags.Instance Or 
                  BindingFlags.Public, 
                  Nothing, 
                  conn, 
                  Nothing), String)
            End If
            System.Runtime.InteropServices.Marshal.ReleaseComObject(conn)
        End If
        System.Runtime.InteropServices.Marshal.ReleaseComObject(dlink)
End Sub

Conclusion

Obviously instantiating COM objects this way is going to save you from having to declare the reference, but for that bit it buys you there is a price.  The costs are dynamic invocation is more error prone, and executes more slowly than early bound code.  In this case I think these costs are acceptable because a little additional testing can flush out any issues in this small bit of code, and since this is a UI component that would likely not be used frequently a few extra tenths of a second will likely not be an issue.

Refrences

Connection String Information: